//  Hess, Schmitz, Naegele & Stiemke (2023): You will take care of me when I am old: Norms on caregiver obligations – an analysis with data of the European Values Survey. Journal of Family Research

** (1) Prepare country level data
import excel "`0722CountriesEurope.xls", sheet("Sheet1") firstrow clear
destring cntry_test , generate(merger)
gen merger = cntry_test 
save "`CountryData.dta", replace



*** (2) Append macro data
global raw "|| data_folder ||"
global eurosurvey5 "`ZA7505_v2-0-0"
global macro "`CountryData"
use $eurosurvey5, clear 
keep if wave==5
gen merger = cntry
keep D026_05 X001 X011 X025A_01 X028 X007 F034 X007 X047E_EVS5 X025A_01 X028 X002 A009 E033 year merger gwght
merge m:m merger using $macro



*** (3) Prepare data
mvdecode D026_05 X001 X011 X025A_01 X028 X007 F034 X007 X047E_EVS5 X025A_01 X028 A009 E033 X002, mv(-1=. \ -2=.\ -5=.)

* (3.1) Dependent variable: Carevalue 
rename D026_05 carevalue 
tab carevalue
gen carevalue2=carevalue
recode carevalue2 (1=5) (2=4) (3=3) (4=2) (5=1) //Recode so that higher values equal higher duty/social norms

* (3.2) Explanatory variables individual level
rename X001 gender //Gender
gen age=year-X002 //Year of birth
gen agecat=age
recode agecat (18/39=1) (40/59=2) (60/83=3)
rename X011 children //Children
replace children=1 if children>1  
rename A009 health  //Health
recode health (1=5) (2=4) (3=3) (4=2) (5=1) //Recode so that higher values equal better health
gen healthcat=health
recode healthcat (1=1) (2=1) (3=1) (4=2) (5=2)
gen education=1 if X025A_01<3 //Education
replace education=2 if X025A_01==3
replace education=2 if X025A_01==4
replace education=3 if X025A_01>4  
gen employment=1 if X028<4 //Employment
replace employment=2 if X028>3   
gen mstatus=1 if X007<3 //Marital status
replace mstatus=2 if X007>2   
rename F034 religion //Religion


* (3.3) Macro level
rename Currenthealthexpenditureof healthexp
rename Laborforceparticipationrate femforce
rename cntry_test country

* (3.4) Missings
*Listwise deletion
drop if carevalue2==. | gender ==. | age==. | health==. | education==. | employment==. | mstatus==. | children==.  | religion==. | country==. | healthexp==. | femforce==.
* obs. n=54,880
* groups n=35



*** (4) Multilevel models

* (4.1) Nullmodell
xtmixed carevalue2 [pweight=gwght] || country:, mle
estat icc
estat ic

* (4.2) Random Intercept

*M1
*Only individual level independent variables
xtmixed carevalue2 b2.gender b1.agecat b1.healthcat b1.education b2.employment b2.mstatus children b1.religion [pweight=gwght] || country:, mle
estat icc
estat ic


*M2
*Including individual- and macro level independent variables
xtmixed carevalue2 b2.gender b1.agecat b1.healthcat b1.education b2.employment b2.mstatus children b1.religion healthexp femforce [pweight=gwght] || country:, mle
estat icc
estat ic

*(4.3) Random Slope
*Assumption that the relationship between carevalue and gender varies across countries

*M1
*Only individual level independent variables
xtmixed carevalue2 b2.gender b1.agecat b1.healthcat b1.education b2.employment b2.mstatus children b1.religion [pweight=gwght] || country: b2.gender,  covariance(unstructured) mle 
estat icc
estat ic

*M2
*Including individual- and macro level independent variables
xtmixed carevalue2 b2.gender b1.agecat b1.healthcat b1.education b2.employment b2.mstatus children b1.religion healthexp femforce [pweight=gwght] || country: b2.gender, covariance(unstructured) mle
estat icc
estat ic

*M3
*Including cross-level interaction to explain gender differences
xtmixed carevalue2 b2.gender c.femforce#b2.gender b1.agecat b1.healthcat b1.education b2.employment b2.mstatus children b1.religion healthexp femforce [pweight=gwght] || country: b2.gender, covariance(unstructured) mle
estat icc
estat ic
testparm gender#c.femforce
margins, dydx(gender) at(femforce=(10(10)100))
marginsplot, yscale(range(-1 1))



*** (5.) Descriptive analyses & effect sizes
svyset [pweight=gwght]

bysort country: sum carevalue2 [aweight=gwght]
anova carevalue2 country [aweight=gwght]
estat esize

svy: tab agecat
bysort agecat: sum carevalue2 [aweight=gwght]
anova carevalue2 agecat [aweight=gwght]
estat esize

svy: tab gender
bysort gender: sum carevalue2 [aweight=gwght]
anova carevalue2 gender [aweight=gwght]
estat esize

svy: tab healthcat
bysort healthcat: sum carevalue2 [aweight=gwght]
anova carevalue2 healthcat [aweight=gwght]
estat esize

svy: tab education
bysort education: sum carevalue2 [aweight=gwght]
anova carevalue2 education [aweight=gwght]
estat esize

svy: tab employment
bysort employment: sum carevalue2 [aweight=gwght]
anova carevalue2 employment [aweight=gwght]
estat esize

svy: tab mstatus
bysort mstatus: sum carevalue2 [aweight=gwght]
anova carevalue2 mstatus [aweight=gwght]
estat esize

svy: tab children
bysort children: sum carevalue2 [aweight=gwght]
anova carevalue2 children [aweight=gwght]
estat esize

svy: tab religion
bysort religion: sum carevalue2 [aweight=gwght]
anova carevalue2 religion [aweight=gwght]
estat esize